# Страница с описанием товара из каталога компании МДС

# Автор: Адамов Борис <adamov@tversu.ru>
# Дата модификации: 09.07.2005
# ** Здесь могла бы быть ваша реклама. **

@init[]
^use[catalog_view.p]
$res(1)

# Создаем глобальную переменную с таблицей-деревом каталога
# которая много где пригодится при построении страницы каталога
$TREE[^catalog_view:load_tree[]]

# Если определен раздел каталога, выясняем какого типа товары в нем
# и пытаемся создать экземпляр класса данного типа
^if(^form:section.int(0)){

#	# Определяем глобальную переменную содержащую тип товара и текущий раздел
	^if(^TREE.locate($TREE.id eq $form:section)){
		$SECTION[$TREE.fields]
		$GOODTYPE[$SECTION.goodtype]
		
		^try{
#			# Хеш с параметрами для конструктора
			$PARAMS[^hash::create[]]
		
#			# Генерируем исполняемый код для создания экземпляра
#			# необходимого класса
			^process{
				^^use[catalog_goodtype_${GOODTYPE}.p]
				^$CAT[^^catalog_goodtype_${GOODTYPE}::init[^$PARAMS]]
			}
#			# Все! Теперь работаем только с этим экземпляром класса

			$GOOD[^CAT.get_good[$form:id]]

#			# Задаем класс для оформления страницы
			$BODY_CLASS[ pfilter]
		}{
#			# Обработка исключений, которые может генерировать конструктор
#			# Либо ошибки типа parser.compile итп...
			^if($exception.comment eq 'not found along MAIN:CLASS_PATH'){
				$exception.handled(1)
				$ERROR[
					$.title[Ошибка при подключении класса]
					$.descr[Скорее всего раздел каталога находится в стадии разработки, зайдите чуть позже.<br/><br/>
					Комментарии (тип: $exception.type): $exception.comment]
				]
			}
		}
	}
}

$result($res)
#/init


@content[]
^if(def $GOOD){
	^h2[^CAT.show_goodtitle[$GOOD]]
	
	^CAT.show_good[$GOOD]

}{
	^if(def $ERROR){
		^show_error[]
	}{
		^h2[Дымоходные системы]
<p><strong>Schiedel UNI</strong> представляет собой простую и лёгкую в монтаже дымоходную систему,состоящую из серийно выпускаемых элементов полной заводской готовности,которые точно соответствуют друг другу по форме и размерам.</p>
<p><strong>Schiedel UNI</strong> — универсальная и многовариантная дымоходная система.. Она подходит для твёрдого,жидкого и газообразного топлива,а также для высоких и низких температур дымовых газов.</p>
<p>Система UNI испытана немецким институтом строительной физики в Берлине и рекомендована к применению как нечувствительная к влаге дымоходная система.Система UNI имеет российский сертификат пожарной безопасности, сертификат соответствия ГОСТ Р,гигиенический сертификат РФ.</p>
<p>Чтобы узнать больше о дымоходных системах <strong>"Шидель"</strong>, подробнее можно посмотреть файл формата <a href="/info/articles/Schiedel.pdf">PDF</a> (1,86 MB), либо скачать в <a href="/info/articles/Schiedel.zip">архиве zip</a> (1,63 MB).</p>
<ul>
	<li><a href="/production/?section=31">Перейти к каталогу</a></li>
	<li><a href="/prices/price.html?section=31">Перейти к прайс-листу</a></li>
	<li><a href="/info/articles/Schiedel.pdf">Информация о системе UNI (в формате PDF)</a></li>
	<li><a href="/info/articles/Schiedel.zip">Информация о системе UNI (в архиве zip)</a></li>
</ul>
	}
}

#/content



@seo_title[]
^if(def $GOOD){
	$result[^CAT.show_goodtitle[$GOOD]]
}{
	$result[Каталог продукции МДС]
}
#/seo_title

@meta_description[]
^if(def $GOOD){
	$result[^CAT.show_goodtitle[$GOOD]]
}{
	$result[Каталог продукции МДС]
}
#/meta_description

@meta_keywords[]
^if(def $GOOD){
	$result[^CAT.show_goodtitle[$GOOD]]
}{
	$result[Каталог продукции МДС]
}
#/meta_keywords